久久久久久久999_99精品久久精品一区二区爱城_成人欧美一区二区三区在线播放_国产精品日本一区二区不卡视频_国产午夜视频_欧美精品在线观看免费

標(biāo)題: [原創(chuàng)diy]試驗(yàn)紅外遙控小車(chē) [打印本頁(yè)]

作者: lxa0 時(shí)間: 2018-3-12 19:04
標(biāo)題: [原創(chuàng)diy]試驗(yàn)紅外遙控小車(chē)
無(wú)線的、藍(lán)牙的、wifi的。。。。。小車(chē)
都試驗(yàn)過(guò)了
這段時(shí)間試驗(yàn)了紅外遙控的小車(chē)

詳見(jiàn)下：

作者: lxa0 時(shí)間: 2018-3-12 19:07
外觀與電路圖：

作者: lxa0 時(shí)間: 2018-3-12 19:10
所使用的紅外遙控器：

作者: lxa0 時(shí)間: 2018-3-12 19:10
參考原代碼：
僅供參考
不得用于商業(yè)！
違者必究！

;試驗(yàn)紅外遙控小車(chē)匯編代碼
;2018-3-8晚修改完成
;at89c2051--11.0592MHz晶振
;p17與p10分別驅(qū)動(dòng)左右電機(jī),p37驅(qū)動(dòng)led燈

org 0000h
ajmp mm
org 0013h
ajmp tt1

;主程序*********************************************************
org 0100h
mm:nop
mov p1,#00h
mov p1,#00h
mov th1,#00h
mov tl1,#00h
mov tmod,#90h       ;T0設(shè)方式0,T1方式1并打開(kāi)門(mén)控
mov tcon,#04h       ;T1由外部下降沿觸發(fā)中斷
mov ie,#84h          ;開(kāi)INT1和總中斷
mov ip,#04h          ;INT1外部中斷優(yōu)先
mov sp,#4fh          ;設(shè)堆棧入口
mov 08h,#38h       ;開(kāi)始轉(zhuǎn)換紅外波頭
mov 09h,#07h       ;轉(zhuǎn)換8位一組波頭
mov 10h,#30h       ;讀紅外波頭存放首址
mov 11h,#10h       ;讀紅外波頭16個(gè)
mov 20h,#00h       ;所有標(biāo)志位
mov 21h,#00h       ;存放動(dòng)作指令碼
clr p3.7
m0:acall zh
acall dz
acall ccc
sjmp m0

;cc動(dòng)作完成后恢復(fù)相關(guān)的寄存器<不占區(qū)>******************************
ccc:jnb 07h,ccc0
mov 30h,#00h
mov 31h,#00h
mov 32h,#00h
mov 33h,#00h
mov 34h,#00h
mov 35h,#00h
mov 36h,#00h
mov 37h,#00h
mov 38h,#00h
mov 39h,#00h
mov 3ah,#00h
mov 3bh,#00h
mov 3ch,#00h
mov 3dh,#00h
mov 3eh,#00h
mov 3fh,#00h
mov 20h,#00h          ;然后恢復(fù)相關(guān)單元
mov 21h,#00h
setb ex1                   ;全部動(dòng)作完成最后開(kāi)INT1中斷
ccc0:ret

;tt1 T1讀紅外代碼子程序<占用區(qū)2>********************************
org 0200h
tt1:push dph       ;保護(hù)現(xiàn)場(chǎng)
push dpl
push acc
push psw
jb 01h,t3             ;若正在轉(zhuǎn)換則返回
jb 02h,t3             ;若正在動(dòng)作則返回
jb 00h,t2             ;收到遙控引導(dǎo)碼則進(jìn)入接收識(shí)別模式
mov th1,#00h       ;清T1,為接收做準(zhǔn)備
mov tl1,#00h
setb 00h                ;設(shè)接收遙控波頭準(zhǔn)備好標(biāo)志位
setb tr1                ;啟動(dòng)T1
sjmp t3
t2:setb psw.4       ;進(jìn)入?yún)^(qū)2
clr psw.3
mov @r0,th1       ;從30h存放讀進(jìn)的紅外波頭
mov th1,#00h       ;清T1,準(zhǔn)備讀下一位
mov tl1,#00h
inc r0
djnz r1,t3             ;接收0fh個(gè)紅外波頭完成否？
mov 10h,#30h       ;存放波頭首地址
mov 11h,#10h       ;存放波頭數(shù)量
setb 01h                ;設(shè)讀取完成與允許轉(zhuǎn)換標(biāo)志位
clr tr1                   ;關(guān)T1
clr ex1                   ;關(guān)外部中斷1
clr 00h                   ;恢復(fù)接收標(biāo)致位
t3:pop psw
pop acc
pop dpl
pop dph
reti

;zh轉(zhuǎn)換子程序<占用區(qū)1>******************************************
org 0280h
zh:push dph          ;將識(shí)別后的遙控信號(hào)轉(zhuǎn)換成16位動(dòng)作代碼
push dpl
push acc
push psw
setb psw.3             ;進(jìn)入?yún)^(qū)1
clr psw.4
jb 00h,h01             ;若正在接收則返回
jb 02h,h01             ;若正在動(dòng)作則返回
jb 01h,h02             ;若允許轉(zhuǎn)換則繼續(xù)
h01:mov 08h,#38h
mov 09h,#07h
pop psw
pop acc
pop dpl
pop dph
ret
h02:mov a,30h
jnb acc.2,h01          ;以下8條是判別紅外指令的地址碼是否正確
mov a,31h             ;正確時(shí)應(yīng)為HHHL LLHL(11100010B)
jnb acc.2,h01
mov a,32h
jnb acc.2,h01
mov a,36h
jnb acc.2,h01
mov a,33h
jnb acc.1,h01
mov a,34h
jnb acc.1,h01
mov a,35h
jnb acc.1,h01
mov a,37h
jnb acc.1,h01
mov 08h,#38h          ;從38h單元開(kāi)始轉(zhuǎn)換指令碼
h03:mov a,@r0          ;地址碼正確開(kāi)始轉(zhuǎn)換指令碼
jb acc.2,h04
clr 08h                      ;21h的最低位置0
sjmp h05
h04: setb 08h          ;21h的最低位置1
h05: mov a,21h
rl a
mov 21h,a
inc 08h
djnz r1,h03          ;8位指令碼轉(zhuǎn)換完否？
setb 02h                ;設(shè)置允許執(zhí)行動(dòng)作標(biāo)志位
clr 01h                   ;清除允許轉(zhuǎn)換標(biāo)志位
ljmp h01

;dz動(dòng)作子程序<不占區(qū)>**********************************************
org 0300h
dz:push dph
push dpl
push acc
push psw
jb 00h,d01             ;若正在接收則返回
jb 01h,d01             ;若正在轉(zhuǎn)換則返回
jnb 02h,d01             ;允許動(dòng)作否?
mov a,21h
cjne a,#50h,dz2       ;左轉(zhuǎn)?
mov p1,#00h
nop
setb p1.7
nop
sjmp d00a
dz2:mov a,21h          ;右轉(zhuǎn)？
cjne a,#48h,dz3
mov p1,#00h
nop
setb p1.0
nop
sjmp d00a
dz3:mov a,21h          ;前進(jìn)?
cjne a,#44h,dz4
mov p1,#00h
nop
mov p1,#0ffh
nop
sjmp d00a
dz4:mov a,21h
cjne a,#54h,d00a       ;停止？
mov p1,#00h
mov p1,#00h
d00a:nop
mov 20h,#00h          ;清除全部標(biāo)志
mov 21h,#00h          ;清除已完成的動(dòng)作代碼
setb 07h                   ;本次動(dòng)作完成后設(shè)置標(biāo)志
d01:pop psw
pop acc
pop dpl
pop dph
ret

end

作者: wangxiaoming123 時(shí)間: 2018-4-1 14:39
666666666666666666666666666666666666666

作者: lxa0 時(shí)間: 2018-4-2 17:40
昨天把轉(zhuǎn)向改為點(diǎn)動(dòng)
并糾正了接收紅外連碼時(shí)的錯(cuò)誤
代碼暫時(shí)不發(fā)了
有需要的壇友可以和我聯(lián)系

作者: wangyj 時(shí)間: 2018-8-24 22:14
居然用的是匯編語(yǔ)言，真的強(qiáng)啊。順帶一問(wèn)，匯編和C語(yǔ)言那個(gè)更好（學(xué)了C之后只會(huì)用C，看需不需要下功夫好好學(xué)匯編）

作者: cs1225 時(shí)間: 2020-3-29 15:56
師傅，你的電路圖怎么畫(huà)的？》好漂亮

歡迎光臨 (http://m.zg4o1577.cn/bbs/)