久久久久久久999_99精品久久精品一区二区爱城_成人欧美一区二区三区在线播放_国产精品日本一区二区不卡视频_国产午夜视频_欧美精品在线观看免费

標題: 19課:單片機定時器、中斷試驗 [打印本頁]

作者: admin 時間: 2013-5-21 03:14
標題: 19課:單片機定時器、中斷試驗
我們在學單片機時我們第一個例程就是燈的閃爍，那是用延時程序做的，現在回想起來，這樣做不很恰當，為什么呢？我們的主程序做了燈的閃爍，就不能再干其它的事了，難道單片機只能這樣工作嗎？當然不是，我們能用定時器來實現燈的閃爍的功能。例1：查詢方式
ORG 0000H
AJMP START
ORG 30H
START:
MOV P1,#0FFH ;關所燈
MOV TMOD,#00000001B ;定時/計數器0工作于方式1
MOV TH0,#15H
MOV TL0,#0A0H ;即數5536
SETB TR0 ;定時/計數器0開始運行
LOOP:JBC TF0,NEXT ;如果TF0等于1，則清TF0并轉NEXT處
AJMP LOOP ;不然跳轉到LOOP處運行
NEXT:CPL P1.0
MOV TH0,#15H
MOV TL0,#9FH;重置定時/計數器的初值
AJMP LOOP
END AJMP LOOP
END
鍵入程序，看到了什么？燈在閃爍了，這可是用定時器做的，不再是主程序的循環了。簡單地分析一下程序，為什么用JBC呢？TF0是定時/計數器0的溢出標記位，當定時器產生溢出后，該位由0變1，所以查詢該位就可知宇時時間是否已到。該位為1后，要用軟件將標記位清0，以便下一次定時是間到時該位由0變1，所以用了JBC指令，該指位在判1轉移的同時，還將該位清0。
以上程序是能實現燈的閃爍了，可是主程序除了讓燈閃爍外，還是不能做其他的事啊！不，不對，我們能在LOOP：……和AJMP LOOP指令之間插入一些指令來做其他的事情，只要保證執行這些指令的時間少于定時時間就行了。那我們在用軟件延時程序的時候不是也能用一些指令來替代DJNZ嗎？是的，但是那就要求你精確計算所用指令的時間，然后再減去對應的DJNZ循環次數，很不方便，而現在只要求所用指令的時間少于定時時間就行，顯然要求低了。當然，這樣的辦法還是不好，所以我們常用以下的辦法來實現。
程序2：用中斷實現
ORG 0000H ,http://m.zg4o1577.cn
AJMP START
ORG 000BH ;定時器0的中斷向量地址
AJMP TIME0 ;跳轉到真正的定時器程序處
ORG 30H
START:
MOV P1,#0FFH ;關所燈
MOV TMOD,#00000001B ;定時/計數器0工作于方式1
MOV TH0,#15H
MOV TL0,#0A0H ;即數5536
SETB EA ;開總中斷允許
SETB ET0 ;開定時/計數器0允許
SETB TR0 ;定時/計數器0開始運行
LOOP: AJMP LOOP ;真正工作時,這里可寫任意程序
TIME0: ;定時器0的中斷處理程序
PUSH ACC
PUSH PSW ;將PSW和ACC推入堆棧保護
CPL P1.0
MOV TH0,#15H
MOV TL0,#0A0H ;重置定時常數
POP PSW
POP ACC
RETI
END
上面的例程中，定時時間一到，TF0由0變1，就會引發中斷，CPU將自動轉至000B處尋找程序并執行，由于留給定時器中斷的空間只有8個字節，顯然不足以寫下所有有中斷處理程序，所以在000B處安排一條跳轉指令，轉到實際處理中斷的程序處，這樣，中斷程序能寫在任意地方，也能寫任意長度了。進入定時中斷后，首先要保存當前的一些狀態，程序中只演示了保存存ACC和PSW，實際工作中應該根據需要將可能會改變的單元的值都推入堆棧進行保護（本程序中實際不需保存護任何值，這里只作個演示）。
上面的兩個單片機程序運行后，我們發現燈的閃爍非常快，根本分辨不出來，只是視覺上感到燈有些晃動而已，為什么呢？我們能計算一下，定時器中預置的數是5536，所以每計60000個脈沖就是定時時間到，這60000個脈沖的時間是多少呢？我們的晶體震蕩器是12M，所以就是60000微秒，即60毫秒，因此速度是非常快的。如果我想實現一個1S的定時，該怎么辦呢？在該晶體震蕩器瀕率下，最長的定時也就是65。536個毫秒啊！上面給出一個例程。
ORG 0000H
AJMP START
ORG 000BH ;定時器0的中斷向量地址
AJMP TIME0 ;跳轉到真正的定時器程序處
ORG 30H
START:
MOV P1,#0FFH ;關所燈
MOV 30H,#00H ;軟件計數器預清0
MOV TMOD,#00000001B ;定時/計數器0工作于方式1
MOV TH0,#3CH
MOV TL0,#0B0H ;即數15536
SETB EA ;開總中斷允許
SETB ET0 ;開定時/計數器0允許
SETB TR0 ;定時/計數器0開始運行
LOOP: AJMP LOOP ;真正工作時,這里可寫任意程序
TIME0: ;定時器0的中斷處理程序
PUSH ACC
PUSH PSW ;將PSW和ACC推入堆棧保護
INC 30H
MOV A,30H
CJNE A,#20,T_RET ;30H單元中的值到了20了嗎?
T_L1: CPL P1.0 ;到了,取反P10
MOV 30H,#0 ;清軟件計數器
T_RET:
MOV TH0,#15H
MOV TL0,#9FH ;重置定時常數
POP PSW
POP ACC
RETI
END
先自己分析一下，看看是怎么實現的？這里采用了軟件計數器的概念，思路是這樣的，先用定時/計數器0做一個50毫秒的定時器，定時是間到了以后并不是立即取反P10，而是將軟件計數器中的值加1，如果軟件計數器計到了20，就取反P10，并清掉軟件計數器中的值，不然直接返回，這樣，就變成了20次定時中斷才取反一次P10，因此定時時間就延長了成了20*50即1000毫秒了。
這個思路在工程中是非常有用的，有的時候我們需要若干個定時器，可51中總共才有2個，怎么辦呢？其實，只要這幾個定時的時間有一定的公約數，我們就能用軟件定時器加以實現，如我要實現P10口所接燈按1S每次，而P11口所接燈按2S每次閃爍，怎么實現呢？對了我們用兩個計數器，一個在它計到20時，取反P10，并清零，就如上面所示，另一個計到40取反P11，然后清0，不就行了嗎？這部份的程序如下
ORG 0000H
AJMP START
ORG 000BH ;定時器0的中斷向量地址
AJMP TIME0 ;跳轉到真正的定時器程序處
ORG 30H
START:
MOV P1,#0FFH ;關所燈
MOV 30H,#00H ;軟件計數器預清0
MOV TMOD,#00000001B ;定時/計數器0工作于方式1
MOV TH0,#3CH
MOV TL0,#0B0H ;即數15536
SETB EA ;開總中斷允許
SETB ET0 ;開定時/計數器0允許
SETB TR0 ;定時/計數器0開始運行
LOOP: AJMP LOOP ;真正工作時,這里可寫任意程序
TIME0: ;定時器0的中斷處理程序
PUSH ACC
PUSH PSW ;將PSW和ACC推入堆棧保護
INC 30H
INC 31H ;兩個計數器都加1
MOV A,30H
CJNE A,#20,T_NEXT ;30H單元中的值到了20了嗎?
T_L1: CPL P1.0 ;到了,取反P10
MOV 30H,#0 ;清軟件計數器
T_NEXT:
MOV A,31H
CJNE A,#40,T_RET ;31h單元中的值到40了嗎?
T_L2:
CPL P1.1
MOV 31H,#0 ;到了,取反P11,清計數器,返回
T_RET:
MOV TH0,#15H
MOV TL0,#9FH ;重置定時常數
POP PSW
POP ACC
RETI
END
您能用定時器的辦法實現前面講的流水燈嗎？試試看。

作者: danpianji889 時間: 2013-8-15 11:14
非常好，謝謝

作者: sjztjk 時間: 2013-8-17 15:06
學習了，謝謝分享。

作者: 雪中梅花 時間: 2014-6-5 14:09
謝謝樓主軟件通過下載試驗收獲很大。

作者: windljn 時間: 2014-7-15 15:35
支持樓主

作者: lxl2255 時間: 2015-1-4 10:05
#在學習了非常好這里快支持樓主速回復#

作者: kaka3511 時間: 2015-2-7 17:21
怎么感覺有點難，是不是我太笨了？

作者: kaka3511 時間: 2015-2-7 17:31
我有一頭小毛驢我從來也不騎

作者: 云龍騰海 時間: 2015-4-21 10:21
我想要c語言的，，，，

作者: 好男人就是我 時間: 2015-4-23 08:37
感謝分享～！！！

作者: yzl 時間: 2015-6-2 14:16
此文講解非常清楚初學者一看一目了然加快了初學者學習決心

作者: yzl 時間: 2015-6-2 14:25
1說理清楚使學者一目了然

作者: 阿桑 時間: 2015-9-6 20:24
好，非常感謝。謝謝

作者: wkuz2222 時間: 2015-12-19 12:06
wsfa aewfaewf

作者: a1097994700 時間: 2016-4-6 16:25

回帖支持！

作者: ln7812 時間: 2016-6-26 14:32
看君一貼編程實例，勝讀十天書。謝謝樓主，學習了，

作者: abc_123 時間: 2016-10-24 09:04
很好，謝謝

作者: lsrly 時間: 2016-11-15 23:14
怎么不是C呀！

作者: a88mm 時間: 2016-12-17 14:16
目測匯編的用最必要的步驟實現，省去了不必要的步驟

作者: 鏡花水月K12 時間: 2017-4-20 11:22

很棒

作者: 123456LYH 時間: 2017-8-16 19:44
非常詳細

作者: zjy007 時間: 2017-10-20 15:08
匯編看著舒不舒服，但簡單直接

作者: 990259743 時間: 2017-10-22 19:33

學習了，謝謝分享

。

作者: DGP 時間: 2017-11-23 09:48
看著匯編代碼腦袋疼

作者: chaoself 時間: 2018-2-7 23:24
學習了，謝謝分享

作者: wuzjh 時間: 2018-2-11 22:13
謝謝老師！受益非淺。

作者: heron 時間: 2018-3-8 23:33
跟著例子做的定時器中斷實現流水燈實驗，歡迎指正錯誤（沒鎖大寫通篇小寫，湊活著看看吧

）

org 0000h
ajmp start
org 000bh
ajmp time0
org 30h
start:
  mov p1,#0feh             ；賦值11111110b，為了實現流水，先打開了一顆燈
  mov 30h,#00h
  mov tmod,#00000001b
  mov th0,#3ch
  mov tl0,#0b0h
  setb ea
  setb et0
  setb tr0
loop:ajmp loop
time0:
  push acc
  push psw
  inc 30h
  mov a,30h
  cjne a,20,t_next
  t_0:
mov a,p1
rl a                      ；左移一位
mov p1,a
mov 30h,#0
  t_next:
mov th0,#15h
mov tl0,#9fh

  pop psw
  pop acc
  reti
end

作者: fscommand 時間: 2018-4-30 09:08
可惜不是c寫的，看不懂

作者: keneng 時間: 2018-6-26 13:54
繼續學習，感謝樓主了。

作者: 18339183028 時間: 2019-1-29 12:33
沒學匯編

作者: 尼古拉斯-趙四 時間: 2020-2-12 14:47
樓主能解釋一下那個END AJMP LOOP啥意思嗎，還有他后面的END是多余的

作者: 尼古拉斯-趙四 時間: 2020-2-12 18:44
ORG 0000H AJMP START ORG 000BH AJMP TIME0 ORG 30H START: MOV P2,#0FEH MOV 30H,#00H MOV TMOD,#00000001B MOV TH0,#15H MOV TL0,#0A0H SETB ET0 SETB EA SETB TR0 LOOP: AJMP LOOP TIME0: PUSH ACC PUSH PSW INC 30H MOV A,30H CJNE A,#20,T_L1 T_L2: MOV A,P2 RL A MOV P2,A MOV 30H,#00H T_L1: MOV TH0,#15H MOV TL0,#9FH POP PSW POP ACC RETI END

作者: 湖南孵化 時間: 2020-3-9 22:57
就喜歡匯編代碼的簡潔有力，清晰明了

作者: sfes1314 時間: 2021-11-3 16:08
是不是少了一句？31H沒有賦初值吧？？

歡迎光臨 (http://m.zg4o1577.cn/bbs/)