久久久久久久999_99精品久久精品一区二区爱城_成人欧美一区二区三区在线播放_国产精品日本一区二区不卡视频_国产午夜视频_欧美精品在线观看免费

標題: 學習型紅外遙控8路輸出端——巧妙利用家里的舊遙控器 [打印本頁]

作者: qq704661078 時間: 2015-5-14 00:01
標題: 學習型紅外遙控8路輸出端——巧妙利用家里的舊遙控器
本帖最后由 qq704661078 于 2015-12-26 23:09 編輯

以前在論壇都持觀望態度，今天第一次發帖，希望對大家有所幫助！因本人對匯編語言情有獨鐘，所以本程序用匯編語言編寫，經過測試，MP3和電視機的遙控都能學習對鍵成功，其他遙控因為手頭沒有，所以不敢保證全部支持！P1口作為輸出口，我分別接了8個燈做指示，如果連上8路繼電器，就可紅外控制8路電器的工作，雖然紅外遙控受遙控距離及方向的影響用起來不夠順心，但在房間里是完全夠用了的！紅外接收頭接P3.7腳；8個學習鍵是利用P3.0和P3.1輪流輸出低電平與P3.2/3.3/3.4/3.5形成2*4矩陣鍵盤。短按按鍵可分別手動控制輸出端；長按某鍵5秒左右則進入學習模式，相應輸出端的指示燈亮起（學習指示燈與輸出指示燈復用，其實學習模式應該是閃爍狀態，但我沒寫這方面的程序，有需要的自己加進去�。�，在5秒內用遙控器對著接收頭按一次遙控的一個鍵（隨自己愛好），學習指示燈熄滅，學習成功！如果要刪除遙控鍵，則長按按鍵至學習模式后不按遙控器，5秒后學習指示燈熄滅，原來學習的遙控鍵數據被刪除，遙控器不能再控制這一路輸出，有需要了再重新學習此路！下面曬幾張我自制的實驗板：圖片壓縮了，不然發不上來！��！——板子可插紅外接收頭、315M無線發射/接收模塊�。�！
（1）、插紅外接收頭：

（2）、背面連接線路：

（3）、插315M無線接收模塊：

（4）、插315M無線發射模塊：

Text1.rar (3.79 KB, 下載次數: 136)
程序更新...：
因之前發布的程序還存在小Bug，正好今天有空，就把最新的程序貼上來吧！此次更新主要解決以下問題：按某個鍵后5S內再按另外一個鍵會誤判斷進入第二個鍵的學習模式...（在按鍵掃描部分加了一些處理動作）
好了，不多說，看程序吧：

;;;STC12C2052/STC12C56**學習型紅外遙控8路繼電器
;;;內部RC振蕩器約6MHz;;;
;;;寫EEPROM數據不能調公共的"寫",所以每1路的學習模式里
;;;都要重復寫一堆相同的程序,感覺有點浪費空間了,郁悶ing...
;;;修改日期2015/10/10;;;

;----------------------
   ISP_DATA  EQU 0E2H ;定義EEPROM相關寄存器
   ISP_ADDRH EQU 0E3H ;此類寄存器地址需參考所用單片機的手冊來設置
   ISP_ADDRL EQU 0E4H ;STC12C2052和56**系列的地址是E2H~E7H
   ISP_CMD EQU 0E5H
   ISP_TRIG  EQU 0E6H
   ISP_CONTR EQU 0E7H

;----------------------
   AUXR  EQU 08EH ;定時器1T/12T時鐘模式控制
   IRCOM EQU 20H    ;RAM中接收到的鍵值起始存放地址(20H-23H)
   Z EQU 00H       ;長按標志位
   X EQU 01H       ;接收完成標志位
   D EQU 02H       ;學習模式標志位

   IRIN EQU  P3.7 ;紅外接收頭
   K1 EQU  P3.2 ;學習鍵 (P3.0與P3.1輪流輸出0)
   K2 EQU  P3.3 ;學習鍵 (實現2*4矩陣鍵盤)
   K3 EQU  P3.4 ;學習鍵
   K4 EQU  P3.5 ;學習鍵
   LED8 EQU  P1.0 ;OUT8
   LED7 EQU  P1.1 ;OUT7
   LED6 EQU  P1.2 ;OUT6
   LED5 EQU  P1.3 ;OUT5
   LED4 EQU  P1.4 ;OUT4
   LED3 EQU  P1.5 ;OUT3
   LED2 EQU  P1.6 ;OUT2
   LED1 EQU  P1.7 ;OUT1

;----------------------
   ORG 0000H
   LJMP START       ;跳初始化
   ORG 000BH
   LJMP T0INT       ;T0中斷服務子程序入口
   ORG 0030H

;----------------------
START: MOV SP,#5FH
   MOV R0,#20H
LP0: MOV @R0,#00H ;20H-43H清零
   INC R0
   CJNE  R0,#44H,LP0
   MOV P3,#0FFH ;P3口置1
   MOV AUXR,00H ;T0/12T時鐘模式
   MOV TMOD,#01H ;定時器工作模式1(16位)
   SETB  EA       ;開總中斷EA
   SETB  ET0       ;開T0中斷ET0
   CLR  Z
   CLR  X
   CLR  D

;-----------------------
MAIN:                   ;主程序
   ACALL IR_IN
   ACALL KEYP30    ;矩陣鍵盤掃描
   ACALL KEYP31    ;矩陣鍵盤掃描
   AJMP MAIN

;-----------------------
;(紅外接收譯碼)
;-----------------------
IR_IN: JNB  IRIN,I2    ;等待 IR 信號出現,IRIN=0則跳到I2
   AJMP  IEND       ;如果沒有接收到紅外信號則先跳出

I2: MOV  R1,#30
I20: ACALL  DEL
   DJNZ  R1,I20    ;延時去抖動
   JB IRIN,IR_IN    ;確認IR信號,去抖動后IRIN仍為0則往下執行
I21: JB  IRIN,I3    ;持續4.5mS的低電平,等IRIN為1后跳到I3
   AJMP  I21       ;此處循環等待高電平的到來

I3: MOV R0,#IRCOM
   MOV  R3,#0       ;8位計數器清0
LL: JNB  IRIN,I4    ;持續4.5mS的高電平,等IRIN為0后跳到I4
   AJMP  LL       ;此處循環等待低電平的到來
;;;;;以上I1-I3程序完成引導碼的確認（4.5mS低電平+4.5mS高電平）;;;;;

I4: JB  IRIN,I5    ;持續0.565mS的低電平,等IRIN為1后跳到I5
   AJMP  I4       ;此處循環等待高電平的到來

I5: MOV  R2,#0       ;高電平到來后開始0.14mS計一次數
L1: ACALL  DEL
   JB  IRIN, N1    ;IRIN為1則跳N1繼續計數

   MOV  A,#8       ;計算高電平長度
   CLR  C          ;減前清進/借位c
   SUBB  A,R2       ;以R2的值判斷此位的高/低(R2<8為0;R2>8為1)
                     ;計數值<8則此位為0（即8-R2;c=0）
   MOV  A,@R0
   RRC  A
   MOV  @R0,A       ;將接收到的一位存入對應的鍵值緩存區
   INC  R3          ;處理完一位
   CJNE  R3,#8,LL ;需收集8位
   MOV  R3,#0       ;收集到1字節
   INC  R0          ;需收集4字節
   CJNE  R0,#24H,LL  ;用戶碼+用戶碼+操作碼+操作反碼

   SETB X          ;接收完成標志位置1
   JB D,IEND       ;如果D=1說明是學習模式跳過鍵值對比
   AJMP  DK       ;跳到鍵值對比區

N1: INC  R2          ;0.14mS R2加一次
   CJNE  R2,#30,L1 ;0.14ms 計數過長則時間到自動離開
IEND:  RET

;-----------------------
; DELAY_0.14MS(以12M晶振/12T計算)
;-----------------------
DEL: ;IR解碼使用(1+2+128+2+4+4=141uS=0.14mS)
   MOV  R5,#3    ;內部約6M/1T,3次;;;12M/1T,6次
DEL0:  MOV  R6,#2    ;1uS
DEL1:  MOV  R7,#32    ;1uS*2次=2uS
   DJNZ  R7,$    ;32*2uS*2次=128uS
   nop             ;1uS*2次=2uS
   DJNZ  R6,DEL1 ;2uS*2次=4uS
   DJNZ  R5,DEL0 ;(1T單片機)
   RET             ;2uS+(acall的)2uS=4uS

;-----------------------
DK: MOV R0,#24H    ;內部鍵值起始存放地址
   MOV DPTR,#00H    ;第1扇區起始地址
   MOV R1,#4       ;讀4個字節
DP1: ACALL EEPROMR    ;讀一字節
   MOV @R0,A       ;讀出的數據存到相應地址
   INC R0          ;內存地址加一
   INC DPTR       ;地址指針加一
   DJNZ R1,DP1    ;循環讀完4字節

   MOV DPTR,#200H ;第2扇區起始地址
   MOV R1,#4       ;讀4個字節
DP2: ACALL EEPROMR    ;讀一字節
   MOV @R0,A       ;讀出的數據存到相應地址
   INC R0          ;內存地址加一
   INC DPTR       ;地址指針加一
   DJNZ R1,DP2    ;循環讀完4字節

   MOV DPTR,#400H ;第3扇區起始地址
   MOV R1,#4       ;讀4個字節
DP3: ACALL EEPROMR    ;讀一字節
   MOV @R0,A       ;讀出的數據存到相應地址
   INC R0          ;內存地址加一
   INC DPTR       ;地址指針加一
   DJNZ R1,DP3    ;循環讀完4字節

   MOV DPTR,#600H ;第4扇區起始地址
   MOV R1,#4       ;讀4個字節
DP4: ACALL EEPROMR    ;讀一字節
   MOV @R0,A       ;讀出的數據存到相應地址
   INC R0          ;內存地址加一
   INC DPTR       ;地址指針加一
   DJNZ R1,DP4    ;循環讀完4字節

   MOV DPTR,#800H ;第5扇區起始地址
   MOV R1,#4       ;讀4個字節
DP5: ACALL EEPROMR    ;讀一字節
   MOV @R0,A       ;讀出的數據存到相應地址
   INC R0          ;內存地址加一
   INC DPTR       ;地址指針加一
   DJNZ R1,DP5    ;循環讀完4字節

   MOV DPTR,#0A00H ;第6扇區起始地址
   MOV R1,#4       ;讀4個字節
DP6: ACALL EEPROMR    ;讀一字節
   MOV @R0,A       ;讀出的數據存到相應地址
   INC R0          ;內存地址加一
   INC DPTR       ;地址指針加一
   DJNZ R1,DP6    ;循環讀完4字節

   MOV DPTR,#0C00H ;第7扇區起始地址
   MOV R1,#4       ;讀4個字節
DP7: ACALL EEPROMR    ;讀一字節
   MOV @R0,A       ;讀出的數據存到相應地址
   INC R0          ;內存地址加一
   INC DPTR       ;地址指針加一
   DJNZ R1,DP7    ;循環讀完4字節

   MOV DPTR,#0E00H ;第8扇區起始地址
   MOV R1,#4       ;讀4個字節
DP8: ACALL EEPROMR    ;讀一字節
   MOV @R0,A       ;讀出的數據存到相應地址
   INC R0          ;內存地址加一
   INC DPTR       ;地址指針加一
   DJNZ R1,DP8    ;循環讀完4字節

   MOV A,20H       ;接收到的用戶碼
   CJNE A,24H,D1    ;與內部存放的對比
   MOV A,21H       ;接收到的用戶反碼
   CJNE A,25H,D1    ;與內部存放的對比
   MOV A,22H       ;接收到的操作碼
   CJNE A,26H,D1    ;與內部存放的對比
   MOV A,23H       ;接收到的操作反碼
   CJNE A,27H,D1    ;與內部存放的對比
   CPL LED1       ;都相同,則取反輸出1狀態

D1: MOV A,20H       ;接收到的用戶碼
   CJNE A,28H,D2    ;與內部存放的對比
   MOV A,21H       ;接收到的用戶反碼
   CJNE A,29H,D2    ;與內部存放的對比
   MOV A,22H       ;接收到的操作碼
   CJNE A,2AH,D2    ;與內部存放的對比
   MOV A,23H       ;接收到的操作反碼
   CJNE A,2BH,D2    ;與內部存放的對比
   CPL LED2       ;都相同,則取反輸出2狀態

D2: MOV A,20H       ;接收到的用戶碼
   CJNE A,2CH,D3    ;與內部存放的對比
   MOV A,21H       ;接收到的用戶反碼
   CJNE A,2DH,D3    ;與內部存放的對比
   MOV A,22H       ;接收到的操作碼
   CJNE A,2EH,D3    ;與內部存放的對比
   MOV A,23H       ;接收到的操作反碼
   CJNE A,2FH,D3    ;與內部存放的對比
   CPL LED3       ;都相同,則取反輸出3狀態

D3: MOV A,20H       ;接收到的用戶碼
   CJNE A,30H,D4    ;與內部存放的對比
   MOV A,21H       ;接收到的用戶反碼
   CJNE A,31H,D4    ;與內部存放的對比
   MOV A,22H       ;接收到的操作碼
   CJNE A,32H,D4    ;與內部存放的對比
   MOV A,23H       ;接收到的操作反碼
   CJNE A,33H,D4    ;與內部存放的對比
   CPL LED4       ;都相同,則取反輸出4狀態

D4: MOV A,20H       ;接收到的用戶碼
   CJNE A,34H,D5    ;與內部存放的對比
   MOV A,21H       ;接收到的用戶反碼
   CJNE A,35H,D5    ;與內部存放的對比
   MOV A,22H       ;接收到的操作碼
   CJNE A,36H,D5    ;與內部存放的對比
   MOV A,23H       ;接收到的操作反碼
   CJNE A,37H,D5    ;與內部存放的對比
   CPL LED5       ;都相同,則取反輸出5狀態

D5: MOV A,20H       ;接收到的用戶碼
   CJNE A,38H,D6    ;與內部存放的對比
   MOV A,21H       ;接收到的用戶反碼
   CJNE A,39H,D6    ;與內部存放的對比
   MOV A,22H       ;接收到的操作碼
   CJNE A,3AH,D6    ;與內部存放的對比
   MOV A,23H       ;接收到的操作反碼
   CJNE A,3BH,D6    ;與內部存放的對比
   CPL LED6       ;都相同,則取反輸出6狀態

D6: MOV A,20H       ;接收到的用戶碼
   CJNE A,3CH,D7    ;與內部存放的對比
   MOV A,21H       ;接收到的用戶反碼
   CJNE A,3DH,D7    ;與內部存放的對比
   MOV A,22H       ;接收到的操作碼
   CJNE A,3EH,D7    ;與內部存放的對比
   MOV A,23H       ;接收到的操作反碼
   CJNE A,3FH,D7    ;與內部存放的對比
   CPL LED7       ;都相同,則取反輸出7狀態

D7: MOV A,20H       ;接收到的用戶碼
   CJNE A,40H,DEND ;與內部存放的對比
   MOV A,21H       ;接收到的用戶反碼
   CJNE A,41H,DEND ;與內部存放的對比
   MOV A,22H       ;接收到的操作碼
   CJNE A,42H,DEND ;與內部存放的對比
   MOV A,23H       ;接收到的操作反碼
   CJNE A,43H,DEND ;與內部存放的對比
   CPL LED8       ;都相同,則取反輸出8狀態
DEND:  RET

;-----------------------
KEYP30:CLR P3.0       ;P3.0與P3.1輪流輸出0,實現矩陣鍵盤

KEY1:  JB K1,KEY3
   CLR TR0;這兩句是為了防止在快速連按按鍵  (2015/10/10修改)
   MOV 45H,#0;或快速切換按鍵時，誤判斷進入學習模式
   ACALL DELAY30MS ;延時去抖動
   JB K1,KEY3
   ACALL OPEN_T0    ;打開T0計時判斷長按
XH1: JBC Z,XUEXI1    ;長按跳轉到學習1,并清零長按標志
   JNB K1,XH1
   CPL LED1       ;OUT1狀態取反
   RET
XUEXI1:                ;學習1
   MOV DPTR,#00H    ;第1扇區
   ACALL PDSQ       ;讀數判斷扇區是否為空
   MOV P1,#07FH    ;LED1
   SETB D          ;學習模式標志位置1
   ACALL OPEN_T0    ;開T0進行等待計時
DZ1: ACALL IR_IN    ;在5S內循環調用紅外接收程序
   JBC z,XEND1    ;5S后沒接收到新數據則退出
   JNB X,DZ1       ;接收完成標志為0則循環等待
;寫EEPROM數據不能調公共的"寫",所以只能每次
;學習模式里都有一堆程序重復寫,浪費空間了�。。�
   MOV DPTR,#00H    ;第1扇區起始地址;存入新鍵值
   MOV R0,#20H    ;RAM中接收到的鍵值起始存放地址
   MOV R1,#4       ;寫4個字節
LP1: MOV A,@R0
   ACALL EEPROMW    ;寫一字節
   INC R0          ;內存地址加一
   INC DPTR       ;地址指針加一
   DJNZ R1,LP1    ;循環寫完4字節
XEND1: CLR D          ;退出學習模式
   SETB LED1       ;關燈
   RET             ;退出

KEY3:  JB K2,KEY5
   CLR TR0;這兩句是為了防止在快速連按按鍵  (2015/10/10修改)
   MOV 45H,#0;或快速切換按鍵時，誤判斷進入學習模式
   ACALL DELAY30MS ;延時去抖動
   JB K2,KEY5
   ACALL OPEN_T0    ;打開T0計時判斷長按
XH3: JBC Z,XUEXI3    ;長按跳轉到學習3,并清零長按標志
   JNB K2,XH3
   CPL LED3       ;OUT3狀態取反
   RET
XUEXI3:                ;學習3
   MOV DPTR,#400H ;第3扇區
   ACALL PDSQ       ;讀數判斷扇區是否為空
   MOV P1,#0DFH    ;LED3
   SETB D          ;學習模式標志位置1
   ACALL OPEN_T0    ;開T0進行等待計時
DZ3: ACALL IR_IN    ;在5S內循環調用紅外接收程序
   JBC z,XEND3    ;5S后沒接收到新數據則退出
   JNB X,DZ3       ;接收完成標志為0則循環等待

   MOV DPTR,#400H ;第3扇區起始地址;存入新鍵值
   MOV R0,#20H    ;RAM中接收到的鍵值起始存放地址
   MOV R1,#4       ;寫4個字節
LP3: MOV A,@R0
   ACALL EEPROMW    ;寫一字節
   INC R0          ;內存地址加一
   INC DPTR       ;地址指針加一
   DJNZ R1,LP3    ;循環寫完4字節
XEND3: CLR D          ;退出學習模式
   SETB LED3       ;關燈
   RET             ;退出

KEY5:  JB K3,KEY7
   CLR TR0;這兩句是為了防止在快速連按按鍵  (2015/10/10修改)
   MOV 45H,#0;或快速切換按鍵時，誤判斷進入學習模式
   ACALL DELAY30MS ;延時去抖動
   JB K3,KEY7
   ACALL OPEN_T0    ;打開T0計時判斷長按
XH5: JBC Z,XUEXI5    ;長按跳轉到學習5,并清零長按標志
   JNB K3,XH5
   CPL LED5       ;OUT5狀態取反
   RET
XUEXI5:                ;學習5
   MOV DPTR,#800H ;第5扇區
   ACALL PDSQ       ;讀數判斷扇區是否為空
   MOV P1,#0F7H    ;LED5
   SETB D          ;學習模式標志位置1
   ACALL OPEN_T0    ;開T0進行等待計時
DZ5: ACALL IR_IN    ;在5S內循環調用紅外接收程序
   JBC z,XEND5    ;5S后沒接收到新數據則退出
   JNB X,DZ5       ;接收完成標志為0則循環等待

   MOV DPTR,#800H ;第5扇區起始地址;存入新鍵值
   MOV R0,#20H    ;RAM中接收到的鍵值起始存放地址
   MOV R1,#4       ;寫4個字節
LP5: MOV A,@R0
   ACALL EEPROMW    ;寫一字節
   INC R0          ;內存地址加一
   INC DPTR       ;地址指針加一
   DJNZ R1,LP5    ;循環寫完4字節
XEND5: CLR D          ;退出學習模式
   SETB LED5       ;關燈
   RET             ;退出

KEY7:  JB K4,KP30OUT
   CLR TR0;這兩句是為了防止在快速連按按鍵  (2015/10/10修改)
   MOV 45H,#0;或快速切換按鍵時，誤判斷進入學習模式
   ACALL DELAY30MS ;延時去抖動
   JB K4,KP30OUT
   ACALL OPEN_T0    ;打開T0計時判斷長按
XH7: JBC Z,XUEXI7    ;長按跳轉到學習7,并清零長按標志
   JNB K4,XH7
   CPL LED7       ;OUT7狀態取反
   RET
XUEXI7:                ;學習7
   MOV DPTR,#0C00H ;第7扇區
   ACALL PDSQ       ;讀數判斷扇區是否為空
   MOV P1,#0FDH    ;LED7
   SETB D          ;學習模式標志位置1
   ACALL OPEN_T0    ;開T0進行等待計時
DZ7: ACALL IR_IN    ;在5S內循環調用紅外接收程序
   JBC z,XEND7    ;5S后沒接收到新數據則退出
   JNB X,DZ7       ;接收完成標志為0則循環等待

   MOV DPTR,#0C00H ;第7扇區起始地址;存入新鍵值
   MOV R0,#20H    ;RAM中接收到的鍵值起始存放地址
   MOV R1,#4       ;寫4個字節
LP7: MOV A,@R0
   ACALL EEPROMW    ;寫一字節
   INC R0          ;內存地址加一
   INC DPTR       ;地址指針加一
   DJNZ R1,LP7    ;循環寫完4字節
XEND7: CLR D          ;退出學習模式
   SETB LED7       ;關燈
   RET             ;退出

KP30OUT:
   SETB P3.0
   RET

;-----------------------
KEYP31:CLR P3.1       ;P3.0與P3.1輪流輸出0,實現矩陣鍵盤

KEY2:  JB K1,KEY4
   CLR TR0;這兩句是為了防止在快速連按按鍵  (2015/10/10修改)
   MOV 45H,#0;或快速切換按鍵時，誤判斷進入學習模式
   ACALL DELAY30MS ;延時去抖動
   JB K1,KEY4
   ACALL OPEN_T0    ;打開T0計時判斷長按
XH2: JBC Z,XUEXI2    ;長按跳轉到學習2,并清零長按標志
   JNB K1,XH2
   CPL LED2       ;OUT2狀態取反
   RET
XUEXI2:                ;學習2
   MOV DPTR,#200H ;第2扇區
   ACALL PDSQ       ;讀數判斷扇區是否為空
   MOV P1,#0BFH    ;LED2
   SETB D          ;學習模式標志位置1
   ACALL OPEN_T0    ;開T0進行等待計時
DZ2: ACALL IR_IN    ;在5S內循環調用紅外接收程序
   JBC z,XEND2    ;5S后沒接收到新數據則退出
   JNB X,DZ2       ;接收完成標志為0則循環等待

   MOV DPTR,#200H ;第2扇區起始地址;存入新鍵值
   MOV R0,#20H    ;RAM中接收到的鍵值起始存放地址
   MOV R1,#4       ;寫4個字節
LP2: MOV A,@R0
   ACALL EEPROMW    ;寫一字節
   INC R0          ;內存地址加一
   INC DPTR       ;地址指針加一
   DJNZ R1,LP2    ;循環寫完4字節
XEND2: CLR D          ;退出學習模式
   SETB LED2       ;關燈
   RET             ;退出

KEY4:  JB K2,KEY6
   CLR TR0;這兩句是為了防止在快速連按按鍵  (2015/10/10修改)
   MOV 45H,#0;或快速切換按鍵時，誤判斷進入學習模式
   ACALL DELAY30MS ;延時去抖動
   JB K2,KEY6
   ACALL OPEN_T0    ;打開T0計時判斷長按
XH4: JBC Z,XUEXI4    ;長按跳轉到學習4,并清零長按標志
   JNB K2,XH4
   CPL LED4       ;OUT4狀態取反
   RET
XUEXI4:                ;學習4
   MOV DPTR,#600H ;第4扇區
   ACALL PDSQ       ;讀數判斷扇區是否為空
   MOV P1,#0EFH    ;LED4
   SETB D          ;學習模式標志位置1
   ACALL OPEN_T0    ;開T0進行等待計時
DZ4: ACALL IR_IN    ;在5S內循環調用紅外接收程序
   JBC z,XEND4    ;5S后沒接收到新數據則退出
   JNB X,DZ4       ;接收完成標志為0則循環等待

   MOV DPTR,#600H ;第4扇區起始地址;存入新鍵值
   MOV R0,#20H    ;RAM中接收到的鍵值起始存放地址
   MOV R1,#4       ;寫4個字節
LP4: MOV A,@R0
   ACALL EEPROMW    ;寫一字節
   INC R0          ;內存地址加一
   INC DPTR       ;地址指針加一
   DJNZ R1,LP4    ;循環寫完4字節
XEND4: CLR D          ;退出學習模式
   SETB LED4       ;關燈
   RET             ;退出

KEY6:  JB K3,KEY8
   CLR TR0;這兩句是為了防止在快速連按按鍵  (2015/10/10修改)
   MOV 45H,#0;或快速切換按鍵時，誤判斷進入學習模式
   ACALL DELAY30MS ;延時去抖動
   JB K3,KEY8
   ACALL OPEN_T0    ;打開T0計時判斷長按
XH6: JBC Z,XUEXI6    ;長按跳轉到學習6,并清零長按標志
   JNB K3,XH6
   CPL LED6       ;OUT6狀態取反
   RET
XUEXI6:                ;學習6
   MOV DPTR,#0A00H ;第6扇區
   ACALL PDSQ       ;讀數判斷扇區是否為空
   MOV P1,#0FBH    ;LED6
   SETB D          ;學習模式標志位置1
   ACALL OPEN_T0    ;開T0進行等待計時
DZ6: ACALL IR_IN    ;在5S內循環調用紅外接收程序
   JBC z,XEND6    ;5S后沒接收到新數據則退出
   JNB X,DZ6       ;接收完成標志為0則循環等待

   MOV DPTR,#0A00H ;第6扇區起始地址;存入新鍵值
   MOV R0,#20H    ;RAM中接收到的鍵值起始存放地址
   MOV R1,#4       ;寫4個字節
LP6: MOV A,@R0
   ACALL EEPROMW    ;寫一字節
   INC R0          ;內存地址加一
   INC DPTR       ;地址指針加一
   DJNZ R1,LP6    ;循環寫完4字節
XEND6: CLR D          ;退出學習模式
   SETB LED6       ;關燈
   RET             ;退出

KEY8:  JB K4,KP31OUT
   CLR TR0;這兩句是為了防止在快速連按按鍵  (2015/10/10修改)
   MOV 45H,#0;或快速切換按鍵時，誤判斷進入學習模式
   ACALL DELAY30MS ;延時去抖動
   JB K4,KP31OUT
   ACALL OPEN_T0    ;打開T0計時判斷長按
XH8: JBC Z,XUEXI8    ;長按跳轉到學習8,并清零長按標志
   JNB K4,XH8
   CPL LED8       ;OUT8狀態取反
   RET
XUEXI8:                ;學習8
   MOV DPTR,#0E00H ;第8扇區
   ACALL PDSQ       ;讀數判斷扇區是否為空
   MOV P1,#0FEH    ;LED8
   SETB D          ;學習模式標志位置1
   ACALL OPEN_T0    ;開T0進行等待計時
DZ8: ACALL IR_IN    ;在5S內循環調用紅外接收程序
   JBC z,XEND8    ;5S后沒接收到新數據則退出
   JNB X,DZ8       ;接收完成標志為0則循環等待

   MOV DPTR,#0E00H ;第8扇區起始地址;存入新鍵值
   MOV R0,#20H    ;RAM中接收到的鍵值起始存放地址
   MOV R1,#4       ;寫4個字節
LP8: MOV A,@R0
   ACALL EEPROMW    ;寫一字節
   INC R0          ;內存地址加一
   INC DPTR       ;地址指針加一
   DJNZ R1,LP8    ;循環寫完4字節
XEND8: CLR D          ;退出學習模式
   SETB LED8       ;關燈
   RET             ;退出

KP31OUT:
   SETB P3.1
   RET

;-----------------------
DELAY30MS:             ;6M/1T模式延時約30mS
   MOV R7,#6
DL1: MOV R6,#100
DL0: MOV R5,#150
   DJNZ R5,$
   DJNZ R6,DL0
   DJNZ R7,DL1
   RET

;-----------------------
OPEN_T0:                ;打開T0計時
   MOV TH0,#3CH    ;定時器0初值
   MOV TL0,#0B0H    ;內部約6MHz(100ms)
   CLR Z          ;清長按標志
   CLR X          ;接收完成標志位清零
   SETB TR0       ;打開T0
   RET

;-----------------------
T0INT:                               ;T0中斷(判斷長按)
   MOV TH0,#3CH    ;重裝初值
   MOV TL0,#0B0H    ;內部約6MHz(100ms)
   INC 45H                      ;中斷計數約100ms一次
   MOV A,45H
   CJNE A,#30,TOUT1  ;100ms*30=3s
   MOV 45H,#0       ;中斷計數滿30清零
   SETB Z                      ;長按標志位置1
   CLR TR0          ;關閉T0
TOUT1: RETI

;-----------------------
PDSQ:  ACALL EEPROMR    ;讀1個字節判斷扇區是否為空
   CJNE A,#0FFH,ERASE;扇區不為空則擦除扇區
   RET

;-----------------------
;EEPROM相關操作
;-----------------------
ERASE:;擦除
   MOV ISP_ADDRH,DPH ;送高地址
   MOV ISP_ADDRL,DPL ;送低地址
   MOV ISP_CONTR,#83H  ;允許ISP/IAP操作(6~12MHz)
   MOV ISP_CMD,#03H ;扇區擦除
   ACALL ISPCF       ;觸發IAP
   ACALL ISP_DISABLE ;禁止ISP/IAP操作
   RET
;----------------------
EEPROMW:;寫
   MOV ISP_DATA,A    ;ACC里是要寫入的數據
   MOV ISP_ADDRH,DPH ;送高地址
   MOV ISP_ADDRL,DPL ;送低地址
   MOV ISP_CONTR,#83H  ;允許ISP/IAP操作(6~12MHz)
   MOV ISP_CMD,#02H ;送寫命令
   ACALL ISPCF       ;觸發IAP
   ACALL ISP_DISABLE ;禁止ISP/IAP操作
   RET
;----------------------
EEPROMR: ;讀
   MOV ISP_ADDRH,DPH ;送高地址
   MOV ISP_ADDRL,DPL ;送低地址
   MOV ISP_CONTR,#83H  ;允許ISP/IAP操作(6~12MHz)
   MOV ISP_CMD,#01H ;送讀命令
   ACALL ISPCF       ;觸發IAP
   MOV A,ISP_DATA    ;讀出的數據放到ACC
   ACALL ISP_DISABLE ;禁止ISP/IAP操作
   RET
;----------------------
ISPCF: ;觸發ISP/IAP
   MOV ISP_TRIG, #46H  ;以MCU型號來定;STC12C2052(46H/0B9H)
   MOV ISP_TRIG, #0B9H ;11F和15F系列相同(5AH/0A5H)
   NOP
   RET
;----------------------
ISP_DISABLE: ;禁止ISP/IAP操作(出于安全考慮才要)
   MOV ISP_CONTR,#00H
   MOV ISP_CMD,#00H
   MOV ISP_TRIG,#00H
   MOV ISP_ADDRH,#0FFH
   MOV ISP_ADDRL,#0FFH
   RET
;-----------------------
END
新程序的hex代碼長度有1089字節，超過1K了，沒法用我的那塊STC12C1052了，1052才1K字節的ROMo(╯□╰)o......

作者: admin 時間: 2015-5-14 00:35
51黑有你更精彩�。�

作者: liuqin 時間: 2015-5-14 00:38
收藏了有機會我也做一個，樓主的圖片好像沒有上傳成功啊期待中�。。。。。。�！

作者: qq704661078 時間: 2015-5-14 19:03

admin 發表于 2015-5-14 00:35
把樓主的程序貼出來一下為大家省點黑幣：

謝謝壇主了！圖片因為之前沒壓縮，上傳失敗，現在補上了！

作者: qq704661078 時間: 2015-5-14 19:04

liuqin 發表于 2015-5-14 00:38
收藏了有機會我也做一個，樓主的圖片好像沒有上傳成功啊期待中�。。。。。。。�

圖片已補上！謝謝支持！

作者: 1176658950 時間: 2015-5-16 00:09
一個吊字已不能形容了！

作者: 云不肯說 時間: 2015-5-23 23:54
沒有電路圖完全沒法做

作者: lesson18 時間: 2015-5-24 16:33
太好了，可惜沒有C程序

作者: 星星一眨眼 時間: 2015-5-25 07:19
你是個高手。謝謝分享，向高手學習。

作者: qq704661078 時間: 2015-5-25 19:59

云不肯說發表于 2015-5-23 23:54
沒有電路圖完全沒法做

最近挺忙的，沒空用軟件畫了，這是手工畫的，希望可以看得懂！“RF”是紅外接收頭；“P1.0~P1.7”和“地線GND”可以接上排針留出來，方便連接排線到繼電器擴展板，這樣就可以紅外遙控控制8路繼電器的通斷了！

作者: qq704661078 時間: 2015-5-25 20:14

lesson18 發表于 2015-5-24 16:33
太好了，可惜沒有C程序

學習下匯編也好的，可以多了解一下單片機的內部結構！我是兩個都會一點點，但是這個程序我沒有用C語言寫過，所以暫時無法提供C版本的！有需要的自己翻譯一下就好了，而且翻譯后你還能順便學到一點匯編語言！

作者: qq704661078 時間: 2015-5-25 20:15

星星一眨眼發表于 2015-5-25 07:19
你是個高手。謝謝分享，向高手學習。

謝謝支持！我也是在學習路上！

作者: 騰飛的龍 時間: 2015-9-18 22:14
不懂匯編啊

作者: qq704661078 時間: 2015-9-19 08:54

騰飛的龍發表于 2015-9-18 22:14
不懂匯編啊

嘿嘿，匯編其實也不是很難，但是用起來很繁瑣的，我是簡單的程序才用匯編寫，不然頭都要大啊！在這里公布個教程算了

51單片機匯編語言教程.pdf (15.69 MB, 下載次數: 78)

作者: 騰飛的龍 時間: 2015-9-19 10:43

qq704661078 發表于 2015-9-19 08:54
嘿嘿，匯編其實也不是很難，但是用起來很繁瑣的，我是簡單的程序才用匯編寫，不然頭都要大��！在這里公布 ...

我的編譯器編譯不了，要什么編譯器？

作者: qq704661078 時間: 2015-9-19 11:43

騰飛的龍發表于 2015-9-19 10:43
我的編譯器編譯不了，要什么編譯器？

用 Keil uVision2 啊，匯編程序的后綴是（ .asm ）；C語言的后綴是（.c ）；你用對沒有？

作者: 騰飛的龍 時間: 2015-9-19 14:37
就是.asm。不編譯

作者: 騰飛的龍 時間: 2015-9-19 14:37
要把你程序里的；注釋掉是吧

作者: 騰飛的龍 時間: 2015-9-19 14:44
好啦現在編譯通過下進去試試。謝謝分享！

作者: qq704661078 時間: 2015-9-19 15:12
本帖最后由 qq704661078 于 2015-9-19 15:15 編輯

騰飛的龍發表于 2015-9-19 14:37
要把你程序里的；注釋掉是吧

去掉么？不用啊，“；”號后面就是注釋嘛，跟C的“//”一個意思，不知道你怎么會編譯不了……有些語句前面“;”注釋掉是可以不要那幾句，不影響程序功能的！只是為了省ROM

作者: qq704661078 時間: 2015-9-19 15:25

騰飛的龍發表于 2015-9-19 14:37
要把你程序里的；注釋掉是吧

我之前用STC12C1052單片機，只有1KB（0~1023字節）ROM，如果不把那些能省的省掉，ROM就不夠裝了，現在這個程序編譯出來的代碼長度剛好1010字節，只差13個字節就裝滿了

……
如果你有大點容量的單片機，比如STC12C2052/4052/56**系列的都行（其他系列的EEPROM相關寄存器地址不同），也可以把我那些用“；”注釋掉的代碼用起來的！

作者: 騰飛的龍 時間: 2015-9-19 18:13
哦謝謝，學習啦，感覺c順手，第一次接觸匯編。

作者: 騰飛的龍 時間: 2015-9-26 15:44
樓主你好；按你的程序下進單片機怎么沒有紅外輸出啊，看著學習都正常，就是沒有紅外輸出，紅外發射管通過pnp三極管控制發射管的正極，發射管的負極接地。P3.7腳通過1k電阻接三極管的基極驅動紅外發射管，這樣一個對吧。請指教。謝謝！

作者: 騰飛的龍 時間: 2015-9-26 16:00

qq704661078 發表于 2015-5-14 19:04
圖片已補上！謝謝支持！

樓主你好。用遙控器直接遙控板子8個指示燈也不亮。哪里出錯啦？再就是你的板子上紅外接收頭旁邊的小LED時紅外發射管嗎？謝謝

作者: 騰飛的龍 時間: 2015-9-26 16:12
樓主你好，我用的是STC12C5608AD的單片機，以前沒接觸匯編，下載了你的匯編教程，改了IO口。指示燈還是P1口，按鍵改成P2口，接收頭改在P3.2，現在控制不了，哪里的問題呀謝謝指教。

作者: 騰飛的龍 時間: 2015-9-26 22:01

qq704661078 發表于 2015-9-19 08:54
嘿嘿，匯編其實也不是很難，但是用起來很繁瑣的，我是簡單的程序才用匯編寫，不然頭都要大��！在這里公布 ...

謝謝你的匯編教程，很好，又學到新東西啦。呵呵，就是你的這個程序我下進單片機，怎么控制不了

作者: qq704661078 時間: 2015-11-17 22:59

騰飛的龍發表于 2015-9-26 16:00
樓主你好。用遙控器直接遙控板子8個指示燈也不亮。哪里出錯啦？再就是你的板子上紅外接收頭旁邊的小LED時 ...

暈，我這個程序可不是用來發射的，接收頭那個LED也只是普通LED，程序只是接收紅外信號解碼，然后可以學習8個遙控的鍵跟板上的8個按鍵對應，方便用紅外遙控和板上的按鍵都能靈活的控制8路I/O口輸出...

作者: qq704661078 時間: 2015-11-17 23:02

騰飛的龍發表于 2015-9-26 16:00
樓主你好。用遙控器直接遙控板子8個指示燈也不亮。哪里出錯啦？再就是你的板子上紅外接收頭旁邊的小LED時 ...

要學習才可以控制嘛，比如我想用紅外遙控器的“1鍵”控制板上的LED1亮，那我就得長按板上控制LED1的按鍵進入學習模式，然后遙控對著接收頭按“1鍵”，學習成功了，遙控器的“1鍵”才可以控制板上的LED1；明白沒？

作者: qq704661078 時間: 2015-11-17 23:06

騰飛的龍發表于 2015-9-26 15:44
樓主你好；按你的程序下進單片機怎么沒有紅外輸出啊，看著學習都正常，就是沒有紅外輸出，紅外發射管通過pn ...

你誤解了我的程序功能了，我這個不是用來實現 “復制紅外遙控器” ，所以是沒有紅外發射功能的！我板上也沒有紅外發射管，你想要 “復制紅外遙控器” 的程序論壇里也有的，搜一下就出來了

作者: 騰飛的龍 時間: 2015-11-18 16:50

qq704661078 發表于 2015-11-17 23:06
你誤解了我的程序功能了，我這個不是用來實現 “復制紅外遙控器” ，所以是沒有紅外發射功能的！我 ...

謝謝指教，學習啦，

作者: 978794076 時間: 2015-11-19 23:13
樓主太感謝了

作者: 978794076 時間: 2015-11-19 23:15
希望樓主以后多發點有關無線知識大家一塊交流學習學習

作者: 978794076 時間: 2015-11-19 23:20

qq704661078 發表于 2015-5-14 19:03
謝謝壇主了！圖片因為之前沒壓縮，上傳失敗，現在補上了！

大贊一個

作者: ludaijin 時間: 2015-11-24 11:45
一個吊字已不能形容了！

作者: madell 時間: 2015-12-24 11:47
匯編的程序不錯，現在很少了。非常適合。

匯編非常適合，現在很少了，原來基礎都是匯編，

非常棒，看程序，硬件就可以搭起來了。感謝

作者很人性化，為了我們節省黑幣，程序無私奉獻

作者: 51黑ren 時間: 2015-12-26 23:43
樓主的程序，注釋得這么詳細，我一個對匯編不怎么感冒的人都看的懂了三分。趕緊收藏，問一下這個程序能學習空調的編碼嗎？空調的編碼比較長，網上下過好多程序都失敗了..

作者: qq704661078 時間: 2015-12-27 01:01

51黑ren 發表于 2015-12-26 23:43
樓主的程序，注釋得這么詳細，我一個對匯編不怎么感冒的人都看的懂了三分。趕緊收藏，問一下這個程序能學習 ...

空調遙控的編碼好長的，比如格力的一個鍵的鍵碼長度是9個碼也就是72位，修改一下應該可以配對得上，我這個程序是以MP3的遙控編碼格式編的，其他遙控沒試過...還有一種配對方法是記錄高低電平的時長，也是最能適應各種遙控器的，不過現在暫時抽不出時間調試這種方案！

作者: qq704661078 時間: 2015-12-27 01:03

madell 發表于 2015-12-24 12:05
作者很人性化，為了我們節省黑幣，程序無私奉獻

程序有更新，感興趣的話請參考最新程序，之前的有Bug......o(╯□╰)o

作者: madell 時間: 2015-12-29 11:20
效果不錯，謝謝分享

作者: camit 時間: 2015-12-30 21:52
好棒的功能，學習一下

作者: yiyamala 時間: 2016-1-2 15:19
樓主太厲害了

作者: hhdsdy 時間: 2016-1-4 19:31
很棒很精彩，頂一個

作者: BrightBell 時間: 2016-1-4 19:46
這個6，焊接棒啊

作者: 如風而過 時間: 2016-7-4 14:14
樓主焊功一流啊，佩服

作者: zdmjjp 時間: 2016-7-13 11:17
謝謝，學習啦，感覺c順手，第一次接觸匯編。

作者: zdmjjp 時間: 2016-7-13 11:17

效果不錯，謝謝分享

作者: zdmjjp 時間: 2016-7-13 11:18

效果不錯，謝謝分享

作者: brightsm 時間: 2016-7-20 12:58
樓主焊的板子很漂亮呀！

作者: ricky4416 時間: 2016-10-2 23:08
好棒的功能，學習一下

效果不錯，謝謝LZ分享

作者: nanning321 時間: 2018-1-11 19:15
很給力.有空也做一個看看

作者: nanning321 時間: 2018-1-11 22:43
樓主軟硬都很厲害，值得學習。

作者: lilei7003 時間: 2018-7-3 16:02

qq704661078 發表于 2015-9-19 08:54
嘿嘿，匯編其實也不是很難，但是用起來很繁瑣的，我是簡單的程序才用匯編寫，不然頭都要大��！在這里公布 ...

樓主好人！！��！

作者: 路明非. 時間: 2018-7-24 23:25
樓主的電路板焊接的真的六

作者: rayin 時間: 2020-11-15 13:32
這焊接洞洞板的水平太強了

歡迎光臨 (http://m.zg4o1577.cn/bbs/)

<cite id="egws4"></cite>