【Arduino】168種傳感器模塊系列實驗（172）---MX1508雙路馬達驅動

ID:513258 · 發表于 2020-12-5 19:41

37款傳感器與模塊的提法，在網絡上廣泛流傳，其實Arduino能夠兼容的傳感器模塊肯定是不止37種的。鑒于本人手頭積累了一些傳感器和執行器模塊，依照實踐出真知（一定要動手做）的理念，以學習和交流為目的，這里準備逐一動手試試多做實驗，不管成功與否，都會記錄下來——小小的進步或是搞不掂的問題，希望能夠拋磚引玉。

【Arduino】168種傳感器模塊系列實驗（資料+代碼+圖形+仿真）
實驗一百七十二：MX1508 四通道雙路有刷直流馬達驅動模塊 2路直流電機驅動模塊雙H橋步進電機正反轉PWM調速

ID:513258 · 發表于 2020-12-6 08:58

MX1508
是專用單芯片解決方案，芯片內部集成兩路 H 橋驅動電路，可同時驅動轉向電機以及前進后退電機。為電池供電的玩具、低壓或者電池供電的運動控制應用提供了一種集成的有刷直流馬達驅動解決方案。電路內部集成了兩通道采用N溝和P溝功率MOSFET設計的H橋驅動電路，適合于驅動電動玩具車的轉向輪及后輪驅動,(驅動有刷直流馬達或者驅動步進馬達的兩個繞組)。該電路具備較寬的工作電壓范圍（從2V到9.6V）。

ID:513258 · 發表于 2020-12-6 09:02

MX1508內部結構圖

ID:513258 · 發表于 2020-12-6 09:07

MX1508單通道工作時，左轉/右轉通道用于驅動轉向電機，最大持續輸出電流達到 1.2A，最大峰值輸出電流達到 1.5A。前進/后退通道用于驅動前進后退電機，最大持續輸出電流達到 1.4A，最大峰值輸出電流達到 2A；雙通道同時工作時，左轉/右轉通道持續輸出 0.8A 的情況下，前進/后退通道能持續輸出 1.2A。該芯片具備較寬的工作電壓范圍（VM 端供電從 2V 到 8V），可覆蓋 2 節干電池至 5 節干電池的應用。

該專用芯片內置過熱保護電路。驅動電路的負載電流遠大于電路的最大持續電流時，受封裝散熱能力限制，封裝內部芯片的結溫將會迅速升高，一旦超過設定值，內部電路將立即關斷輸出功率管，切斷負載電流，避免溫度持續升高造成塑料封裝冒煙、起火等安全隱患。內置的溫度遲滯電路，確保電路恢復到安全溫度后，才允許重新對電路進行控制。

應用中注意采用PWM控制時，PWM頻率不可太高，高了后無法響應，輸出端并非PWM信號，導致控制失敗，建議采用較低控制頻率，兩路PWM控制，注意不能采用互補控制，有效波形必須全部非高，否則電機剎車。控制電壓建議小于10V，邏輯電平5V為宜。

ID:513258 · 發表于 2020-12-6 09:09

主要特性
a. 低待機電流 (小于0.1uA)；
b. 低靜態工作電流；
c. 集成的H橋驅動電路；
d. 內置防共態導通電路；
e. 低導通內阻的功率MOSFET管；
f. 內置帶遲滯效應的過熱保護電路 (TSD)；
g. 抗靜電等級：3KV (HBM)；
　 h. 集成的 H 橋驅動電路；
　 i. 高度集成方案，集成 RX2 芯片和兩個馬達驅動芯片；
　 j. 內置 2.5V 穩壓 LDO 電路。

典型應用
　　2-5 節 AA/AAA 干電池供電的玩具馬達驅動；
　　2-5 節鎳-氫/鎳-鎘充電電池供電的玩具馬達驅動；
　　1-2 節鋰電池供電的馬達驅動

ID:513258 · 發表于 2020-12-6 09:29

ID:513258 · 發表于 2020-12-6 09:33

ID:513258 · 發表于 2020-12-6 09:34

ID:513258 · 發表于 2020-12-6 09:37

ID:513258 · 發表于 2020-12-6 09:39

ID:513258 · 發表于 2020-12-6 09:42

ID:513258 · 發表于 2020-12-6 09:45

ID:513258 · 發表于 2020-12-6 09:48

ID:513258 · 發表于 2020-12-6 09:51

ID:513258 · 發表于 2020-12-11 10:54

MX1508雙路馬達驅動模塊特點
1.采用專業電機驅動芯片，內置低導通內阻MOS開關管，發熱極小，無需散熱片，體積小，省電，是您電池供電的理想選擇。（相比較L298N內部為晶體管開關，效率低，發熱高，需散熱，體積笨重，市面上的L298N極容易燒壞，都沒有采用原裝芯片，本模塊能夠完美替代）。
2.雙路1.5A*2,峰值電流可到2.5A, 內置過熱保護電路,不用怕電機堵轉燒壞，溫度下降后自動恢復（目前市面上的智能小車電壓和電流都在此范圍內）。
3.體積小，質量輕，0待機電流，是各種模型車載的理想選擇。

ID:513258 · 發表于 2020-12-11 11:15

MX1508雙路馬達驅動模塊主要參數
雙路H橋電機驅動，可以同時驅動兩路直流電機或者1個4線兩相式步進電機；
模塊供電電壓2V-10V;
信號端輸入電壓1.8-7V；
單路工作電流1.5A，峰值電流可達2.5A，低待機電流 (小于 0.1uA)；
內置防共態導通電路，輸入端懸空時，電機不會誤動作；
內置帶遲滯效應的過熱保護電路 (TSD)，無需擔心電機堵轉；
產品尺寸： 24.7*21*5mm (長寬高)，超小體積，適合組裝和車載；
安裝孔直徑：2 mm；
重量：5g 。

ID:513258 · 發表于 2020-12-11 12:41

MX1508雙路馬達驅動模塊電原理圖

ID:513258 · 發表于 2020-12-11 12:59

MX1508雙路馬達驅動模塊接腳圖

ID:513258 · 發表于 2020-12-11 13:05

MX1508 電機驅動邏輯真值表

ID:513258 · 發表于 2020-12-11 13:08

MX1508雙路電機驅動模塊接線示意圖

ID:513258 · 發表于 2020-12-11 16:13

下載安裝MX1508庫

鏈接 https://github.com/Saeterncj/MX1508

ID:513258 · 發表于 2020-12-11 17:25

/*
【Arduino】168種傳感器模塊系列實驗（資料+代碼+圖形+仿真）
實驗一百七十二：MX1508 四通道雙路有刷直流馬達驅動模塊
2路直流電機驅動模塊雙H橋步進電機正反轉PWM調速
1、安裝庫：下載鏈接 https://github.com/Saeterncj/MX1508
2、實驗接線方法
MX1508模塊 Ardunio Uno
GND---------GND接地線
VCC---------5V 接電源
IN1---------D9（PWM）
IN2 ------- D10(PWM)
3、實驗之一：簡易控制電機（MOTOR-A）連續正轉,PWM設置為250
*/
#include <MX1508.h>
#define PINA 9
#define PINB 10
#define NUMPWM 2
#define PWM 250
MX1508 motorA(PINA, PINB, FAST_DECAY, NUMPWM);
void setup() {}
void loop() {
motorA.motorGo(PWM);
}

復制代碼

ID:513258 · 發表于 2020-12-11 18:03

實驗一場景示意圖

ID:513258 · 發表于 2020-12-11 19:45

/*
【Arduino】168種傳感器模塊系列實驗（資料+代碼+圖形+仿真）
實驗一百七十二：MX1508 四通道雙路有刷直流馬達驅動模塊
2路直流電機驅動模塊雙H橋步進電機正反轉PWM調速
1、安裝庫：下載鏈接 https://github.com/Saeterncj/MX1508
2、實驗接線方法
MX1508模塊 Ardunio Uno
GND---------GND接地線
VCC---------5V 接電源
IN1---------D9（PWM）
IN2 ------- D10(PWM)
3、實驗之二：控制電機（MOTOR-A）正轉與反轉,
PWM為0-180，180-0，,逐步加速然后減速，循環
*/
#include <MX1508.h>
#define PINA 9
#define PINB 10
#define NUMPWM 2
MX1508 motorA(PINA, PINB, FAST_DECAY, NUMPWM);
void setup() {
Serial.begin(115200);
}
/*
通過每50毫秒將pwm增加1來將斜坡增加到pwm = 180。
然后通過每50毫秒降低pwm降低到pwm = -180。
正值pwm表示正向。
負值pwm的方向相反。
*/
void loop() {
static unsigned long lastMilli = 0;
static bool cwDirection = true; // 假設初始方向（正pwm）為順時針
static int pwm = 1;
if (millis() - lastMilli > 50) { // 每50毫秒
if (cwDirection && pwm++ > 180 ) {
cwDirection = false;
} else if (!cwDirection && pwm-- < -180) {
cwDirection = true;
}
motorA.motorGo(pwm);
lastMilli = millis();
Serial.println(motorA.getPWM()); // 我們可以只打印pwm，但是僅顯示成員函數getPWM（）起作用。
}
}

復制代碼

ID:513258 · 發表于 2020-12-11 20:03

MX1508庫的幾個函數
1、motorGo（pwmVal）
這將設置PWM val（速度）其值為0-200（數值太小，電機只是抖動而無法轉動，合適的數值需要通過實驗來確定）

2、stopMotor（）
只需停止電動機

3、setResolution（pwmResolution）
可以更改pwm的分辨率。要使用此功能，必須使用arduino nano / uno的9和10的pwm可以實現16位PWM。理論上，該值可以在0-65535之間的任何值）

說明：
MX1508電機驅動器的主要缺點之一是需要PWM引腳，每1臺電機需要2 pwm引腳。通過實驗發現，僅使用一個PWM和任何數字引腳，而不是使用2個不同的PWM引腳是可能的。這是一個巨大的折衷。電機轉動一個方向所獲得的響應不同于電機轉動另一個方向所獲得的響應。在一種方式中，將獲得FAST_DECAY響應（線性響應，看起來像一個“ V”），然后在另一種情況下，將獲得SlOW_DECAY響應（積極反應，看起來像個“ U”）。僅當絕對沒有更多的PWM引腳時才應使用此功能。

ID:513258 · 發表于 2020-12-11 20:16

MX1508.h文件

#ifndef MX1508_h
#define MX1508_h
#include "Arduino.h"
typedef enum
{
FAST_DECAY = 0, // set non-PWM pin low
SLOW_DECAY = 1 // set non-PWM pin high
} DecayMode;
typedef enum
{
PWM_1PIN = 1,
PWM_2PIN = 2
} NumOfPwmPins;
class MX1508 {
public:
MX1508(uint8_t pinIN1, uint8_t pinIN2); // default fast decay, 2 pwm pins
MX1508(uint8_t pinIN1, uint8_t pinIN2, DecayMode decayMode, NumOfPwmPins numPWM);
void motorGo(long pwmVal); //
void setResolution(unsigned int resolution);
int getPWM();
void stopMotor();
void analogWrite16(uint8_t pin, uint16_t val);
void setPWM16(uint8_t prescaler, unsigned int resolution);
private:
uint8_t _pinIN1;
uint8_t _pinIN2;
bool _useAnalogWrite16 = false;
int _pwmVal;
int _pwmResolution = 255; //max resolution of pwm, default is 255.
DecayMode _whichMode;
NumOfPwmPins _numPwmPins;
};
#endif

復制代碼

ID:513258 · 發表于 2020-12-11 20:19

MX1508.cpp文件

#include "MX1508.h"
MX1508::MX1508( uint8_t pinIN1, uint8_t pinIN2) {
_pinIN1 = pinIN1; // always a PWM pin
_pinIN2 = pinIN2; // can be a non-Pwm pin.
_whichMode = FAST_DECAY;
_numPwmPins = PWM_2PIN;
pinMode(_pinIN1, OUTPUT);
pinMode(_pinIN2, OUTPUT);
}
MX1508::MX1508( uint8_t pinIN1, uint8_t pinIN2, DecayMode decayMode, NumOfPwmPins numPins) {
_pinIN1 = pinIN1; // always a PWM pin
_pinIN2 = pinIN2; // can be a non-Pwm pin.
_whichMode = decayMode;
_numPwmPins = numPins;
pinMode(_pinIN1, OUTPUT);
pinMode(_pinIN2, OUTPUT);
}
int MX1508::getPWM() {
return _pwmVal;
}
void MX1508::stopMotor() {
digitalWrite(_pinIN1, LOW);
digitalWrite(_pinIN2, LOW);
}
void MX1508::setResolution(unsigned int pwmResolution) {
_pwmResolution = pwmResolution;
if(_useAnalogWrite16) ICR1 = pwmResolution;
}
void MX1508::setPWM16(uint8_t prescaler, unsigned int resolution){
if(prescaler > 5 || prescaler == 0) prescaler = 3; // default to 64 if not in range.
DDRB |= _BV(PB1) | _BV(PB2); /* set pin 9and 10 as outputs */
TCCR1A = _BV(COM1A1) | _BV(COM1B1) | _BV(WGM11); // non-inverting PWM, mode 14 fastPWM, TOP =ICR1
TCCR1B = _BV(WGM13) | _BV(WGM12) | prescaler ; // rescaler must be 1->5, 1,8,64,256,1028 respectively
ICR1 = resolution;
_pwmResolution = resolution;
_useAnalogWrite16 = true;
}
void MX1508::analogWrite16(uint8_t pin, uint16_t val)
{
if(_useAnalogWrite16){
if(val < 5) val =5;
switch (pin) {
case 9: OCR1A = val; break;
case 10: OCR1B = val; break;
default: analogWrite(pin,val);
}
}else{
analogWrite(pin, val);
}
}
void MX1508::motorGo(long pwmSpeed) {
_pwmVal = pwmSpeed;
// if set decay mode is set as fast decay mode
if (this->_whichMode == FAST_DECAY) {
if (pwmSpeed >= 0) { //forward fast decay
if(_numPwmPins == PWM_1PIN)digitalWrite(_pinIN2, LOW);
else analogWrite16(_pinIN2, 1);
analogWrite16(_pinIN1, pwmSpeed);
} else if (this->_numPwmPins == PWM_2PIN) { // reverse fast decay
pwmSpeed *= -1;
analogWrite16(_pinIN1, 1);
analogWrite16(_pinIN2, pwmSpeed);
} else if (this->_numPwmPins == PWM_1PIN) { // reverse slow decay
pwmSpeed *= -1;
pwmSpeed = map(pwmSpeed, 0, _pwmResolution, _pwmResolution, 0);
digitalWrite(_pinIN2, HIGH);
analogWrite16(_pinIN1, pwmSpeed);
}
}
// if decay mode is set as slow decay mode
else {
if (pwmSpeed >= 0) { // forward slow decay
pwmSpeed = map(pwmSpeed, 0, _pwmResolution, _pwmResolution, 0);
if(_numPwmPins == PWM_1PIN)digitalWrite(_pinIN1, HIGH);
else analogWrite16(_pinIN1, _pwmResolution);
analogWrite16(_pinIN2, pwmSpeed);
} else if (this->_numPwmPins == PWM_2PIN) { // reverse slow decay
pwmSpeed *= -1;
pwmSpeed = map(pwmSpeed, 0, _pwmResolution, _pwmResolution, 0);
analogWrite16(_pinIN2, _pwmResolution);
analogWrite16(_pinIN1, pwmSpeed);
} else if (this->_numPwmPins == PWM_1PIN) { // reverse fast decay
pwmSpeed *= -1;
digitalWrite(_pinIN1, LOW);
analogWrite16(_pinIN2, pwmSpeed);
}
}
}

復制代碼

ID:513258 · 發表于 2020-12-12 16:57

實驗之三：通過D9和D10的pwm引腳來實現16位PWM
使用功能setPWM16（uint8_t預分頻器，unsigned int分辨率）的Arduino Nano / Uno引腳9和10的分辨率。

快速pwm頻率的公式= MPU（16Mhz）/預分頻器/分辨率的頻率， F_PWM = 16000000 /預分頻器/分辨率

預分頻器參數值必須在1-5之間，分別代表1、8、64、256、1024。分辨率必須為0-65535之間的值。

MX1508（uint8_t pinIN1，uint8_t pinIN2，DecayMode衰減模式，NumOfPwmPins numPWM）;

DecayMode必須為FAST_DECAY或SLOW_DECAY，NumOfPwmPins，對于setPWM16（）函數，其值必須為2，PINA和PINB必須！！！是setPWM16（）函數的引腳9和10 。

示例MX1508 myMotor（10,9，FAST_DECAY，2）。

ID:513258 · 發表于 2020-12-12 16:59

/*
【Arduino】168種傳感器模塊系列實驗（資料+代碼+圖形+仿真）
實驗一百七十二：MX1508 四通道雙路有刷直流馬達驅動模塊
2路直流電機驅動模塊雙H橋步進電機正反轉PWM調速
1、安裝庫：下載鏈接 https://codeload.github.com/Saeterncj/MX1508/zip/master
2、實驗接線方法
MX1508模塊 Ardunio Uno
GND---------GND接地線
VCC---------5V 接電源
IN1---------D9（PWM）
IN2 ------- D10(PWM)
3、實驗之三：通過D9和D10的pwm引腳來實現16位PWM
*/
#include <MX1508.h>
#define PINA 9
#define PINB 10
#define NUMPWM 2
MX1508 motorA(PINA, PINB, FAST_DECAY, 2);
int resolution = 1000;
void setup() {
Serial.begin(115200);
motorA.setPWM16(2, resolution); // 預分頻器為8，分辨率1000，PWM頻率= 16Mhz / 8/1000 = 2000Hz
// prescalar 1=1, 2=8, 3=64, 4=256, 5 =1028
/*------------ setPWM16 Class function is defined as below-----------------
void MX1508::setPWM16(uint8_t prescaler, unsigned int resolution){
if(prescaler > 5 || prescaler == 0) prescaler = 3; // default to 64 if not in range.
DDRB |= _BV(PB1) | _BV(PB2); // set pin 9and 10 as outputs
TCCR1A = _BV(COM1A1) | _BV(COM1B1) | _BV(WGM11); // non-inverting PWM, mode 14 fastPWM, TOP =ICR1
TCCR1B = _BV(WGM13) | _BV(WGM12) | prescaler ;
ICR1 = resolution;
_pwmResolution = resolution;
_useAnalogWrite16 = true;
}
*/
}
/*
通過每50毫秒將pwm增加1，將斜率提高到pwm =分辨率/ 2。
然后通過每50毫秒降低pwm降低到pwm = -resolution / 2。
正值pwm表示正向。
負值pwm的方向相反。
*/
void loop() {
static unsigned long lastMilli = 0;
static bool cwDirection = true; // 假設初始方向（正pwm）為順時針
static int pwm = 1;
if (millis() - lastMilli > 50) { // 每50毫秒
if (cwDirection && pwm++ > resolution / 2 ) {
cwDirection = false;
} else if (!cwDirection && pwm-- < -(resolution / 2)) {
cwDirection = true;
}
motorA.motorGo(pwm);
lastMilli = millis();
Serial.println(motorA.getPWM()); // we can just print pwm but just showing that member function getPWM() works.
}
}

復制代碼

ID:513258 · 發表于 2020-12-14 19:56

實驗開源圖形編程（Mind+、編玩邊學）
通過數字口12和13，簡單控制電機A正轉與反轉

ID:513258 · 發表于 2020-12-14 19:57

實驗開源仿真編程（linkboy3.7）
使用按鍵控制電機1，按下正轉，松開停止

ID:513258 · 發表于 2020-12-24 13:01

【花雕動手做】超迷你哦，用商徽香煙盒做個智能小車！

ID:513258 · 發表于 2020-12-24 13:04

【花雕動手做】超迷你哦，用商徽香煙盒做個智能小車！

ID:513258 · 發表于 2020-12-24 13:06

【花雕動手做】超迷你哦，用商徽香煙盒做個智能小車！

https://v.youku.com/v_show/id_XNTAyMzQ4MzA4OA==.html?spm=a2hzp.8253869.0.0

ID:74784 · 發表于 2021-3-7 18:30

上個MX1508的pdf看看？

ID:710495 · 發表于 2022-1-24 12:47

你好，我最近在用這個模塊的時候出了點問題。我用3.3V供電STC8G2K64S4單片機和mx1508模塊，輸入1和0也就是高低電平電機并不會轉動，只有輸入兩個高電平的時候電機才轉動，而且只能朝一個方向轉動，請問這是什么問題

ID:796416 · 發表于 2022-7-7 01:59

1508有不同的版本，9樓的那張原理圖與其他的電路與模塊實物都不符，發貼前建議檢查確認一下。

帳號		自動登錄	找回密碼
密碼			立即注冊

久久久久久久999_99精品久久精品一区二区爱城_成人欧美一区二区三区在线播放_国产精品日本一区二区不卡视频_国产午夜视频_欧美精品在线观看免费

【Arduino】168種傳感器模塊系列實驗（172）---MX1508雙路馬達驅動