本帖最后由 taotie 于 2021-2-15 13:39 編輯
$crystal = 16000000
$regfile = "m32def.dat"
'$baud = 9600 '串行接口
Dim S As String * 15 , Z As String * 15 '字符串轉(zhuǎn)換變量
'...............................................................................
'ssd1306液晶屏設置
Config Scl = Portc.0 ' 用I2C引腳Scl = Portc.0 ，Sda = Portc.4
Config Sda = Portc.1
Config Twi = 400000 ' i2c 的速度
I2cinit
$lib "i2c_twi.lbx" ' 不使用模擬I2c的軟件，而是使用twi
$lib "glcdSSD1306-I2C.lib" ' 用glcdSSD1306-I2C庫替換默認庫要添加在bascom avr庫中
'#if _build < 20784
'Dim ___lcdrow As Byte , ___lcdcol As Byte ' 老版本變量格式進行編譯
'#endif
Config Graphlcd = Custom , Cols = 128 , Rows = 64 , Lcdname = "SSD1306" '配置圖形顯示器
'-------------------------------------------------------------------
'*****************************************************************
'ADC控制器設置 呵呵~~~直接針對控制寄存器操作
Admux = &B11000000 '內(nèi)部，2.56V，在AREF處有一個電容器,結(jié)果為10位,通道0.
Adcsra = &B11101111 ''ADC使能，開始轉(zhuǎn)換，自動觸發(fā)使能
'，ADIF = 0
'AD int使能，111 =預分頻128
'ADC自動觸發(fā)源設置
Set Sfior.7 '101 =Timer1 匹配B
Reset Sfior.6
Set Sfior.5
'******************************************************************
On Adcc Adcinterrupt
Dim Wadc As Word
'訪問低字節(jié)和高字節(jié):
Dim Wadcl As Byte At Wadc Overlay
Dim Wadch As Byte At Wadc + 1 Overlay
'您可以使用Overlay覆蓋來輕松訪問WORD的低字節(jié)和高字節(jié)
'（同樣的方法也適用于LONG）
'這就是將其存儲在SRAM中的方式
'+ ----------- + ---------- +
'| 低字節(jié)|高字節(jié)|
'+ ----------- + ---------- +
Dim Value As Single
Dim Adkorr1 As Single
Dim Adkorr2 As Single
Dim Adc_complete As Bit
Adkorr1 = 2500 / 2500 '沒有補償。應根據(jù)實物調(diào)試情況修改
Adkorr2 = 0 '這個是不是有點多余？
'......................................................
'Timer1比較->每秒中斷”比較器B被使用，因為它必須用于ADC自動觸發(fā)“但是：比較B，比較值必須在Compare1A中！
Dim Seconds As Long
Compare1a = 15625
'盡管發(fā)生了COMPARE B事件，但仍使用COMPARE1A！
Config Timer1 = Timer , Prescale = 1024 , Clear Timer = 1 , Compare B = Disconnect
On Compare1b Timer1_isr
'Enable Compare1b
TIMSK.OCIE1B=1 '等同Enable Compare1b
'Enable Interrupts
Sreg.7 = 1 '等同Enable Interrupts
'..............................................................................
'ADC準備就緒時，標志Adc_complete為1 '，然后獲取并打印值
Do
If Adc_complete = 1 Then
Adc_complete = 0
Gosub Getvalue
Gosub Printvalues
End If
Loop
'---------------------------------------------------------------
Getvalue: 'Wadc由ADC完整中斷更新，因此我們只需獲取該值
Value = Wadc * 2.56
Value = Value / 1023
Value = Value * Adkorr1 'Adkorr1 2.5v補償系數(shù)
Value = Value + Adkorr2 'Adkorr2 0v顯示補償值
Return
'-------------------------------------------------------------------------------
Printvalues:
cls
Setfont csdy
Lcdat 1, 6 , chr(33);chr(34);chr(35);chr(36);chr(37)
's=Str(Value)
'z=Left(s , 8) '截取采集值前8位數(shù)值
Setfont font12x16
Lcdat 4, 1 ,Value
'Lcdat 4, 8 ,z;"V";" "
'"間隔1秒記錄"：
Lcdat 7, 6 ,"S :";" ";Seconds
Return
'--------------------------------------------------------------------------------
Timer1_isr:
'寄存器ADCSRA和SFIOR中的“增量秒” ADC由硬件自動觸發(fā)，由初始化設置
Incr Seconds
Return
'-------------------------------------------------------------------------------
Adcinterrupt:
'在ADC準備就緒時執(zhí)行 更新Wadc并設置標志Adc_complete
Wadcl = Adcl
Wadch = Adch
Adc_complete = 1
Return
$include "../font12x16.font"
$include "../369.font"
|
