久久久久久久999_99精品久久精品一区二区爱城_成人欧美一区二区三区在线播放_国产精品日本一区二区不卡视频_国产午夜视频_欧美精品在线观看免费

專注電子技術學習與研究
當前位置:單片機教程網 >> MCU設計實例 >> 瀏覽文章

一個自己寫的51單片機時鐘程序

作者:huliedp   來源:本站原創   點擊數:  更新時間:2010年08月29日   【字體:

這是一個自己獨立完成的時鐘程序,已經測試成功,用數碼管來顯示.

HOUR  EQU 030H

MINUTE EQU 031H

SECOND EQU 032H

COUNT1	equ 033H;總計數到4000:拆分成40*100

COUNT2	equ 034H

SPL	EQU 020H;閃爍判斷的依據

SET_BTN EQU 021H;

ORG 0000H

	AJMP MAIN




ORG 001BH

 	AJMP IT_1




ORG 040H










MAIN: 	

	MOV SPL,#00H

	CLR SPL.0

	CLR SPL.1

	CLR SPL.2

	MOV DPTR,#TABLE

	MOV HOUR,#00H

	MOV MINUTE,#00H

	MOV SECOND,#00H

	MOV COUNT1,#00H

	MOV COUNT2,#00H

	MOV TMOD,#20H

	MOV TH1,#06H

	MOV TL1,#06H

	MOV IE,#10001000B;設置允許中斷,并且打開兩個定時器

	SETB TR1

	 

	 

LOOP:	




	JNB P0.0,JUST_TIME

	JB SET_BTN.0,JUST_TIME




	JNB P0.1, SUBB_TIME

	JB SET_BTN.1,SUBB_TIME




	JNB P0.2, ADD_TIME

	JB SET_BTN.2,ADD_TIME




TIME:	ACALL HOUR_SHOW

	ACALL MINUTE_SHOW

	AJMP LOOP

SUBB_TIME:

	JB SET_BTN.1,WAIT_BTN2_UP

	ACALL DELAY2;

	JB P0.1, TIME

	SETB SET_BTN.1

	JB SPL.1,SUBB_HOUR

	JB SPL.2,SUBB_MIN

	AJMP TIME

SUBB_MIN:

	MOV R1,MINUTE 

	CJNE R1,#00H,SUBB_MIN_OPT

	AJMP TIME

SUBB_MIN_OPT:

	DEC MINUTE

	AJMP TIME




SUBB_HOUR:

	MOV R1,HOUR 

	CJNE R1,#00H,SUBB_HOUR_OPT

	AJMP TIME

SUBB_HOUR_OPT:

	DEC HOUR

	AJMP TIME

WAIT_BTN2_UP:

	JNB P0.1,TIME

	CLR SET_BTN.1

	AJMP TIME







ADD_TIME:

	JB SET_BTN.2,WAIT_BTN3_UP

	ACALL DELAY2;

	JB P0.2, TIME

	SETB SET_BTN.2

	JB SPL.1,ADD_HOUR

	JB SPL.2,ADD_MIN

	AJMP TIME

ADD_MIN:

	MOV R1,MINUTE 

	CJNE R1,#3BH,ADD_MIN_OPT

	AJMP TIME

ADD_MIN_OPT:

	INC MINUTE

	AJMP TIME




ADD_HOUR:

	MOV R1,HOUR 

	CJNE R1,#17H,ADD_HOUR_OPT

	AJMP TIME

ADD_HOUR_OPT:

	INC HOUR

	AJMP TIME

WAIT_BTN3_UP:

	JNB P0.2,TIME

	CLR SET_BTN.2

	AJMP TIME







JUST_TIME:

	JB SET_BTN.0,WAIT_UP

	ACALL DELAY2;防抖

	JB P0.0, TIME

	SETB SET_BTN.0 

	JB SPL.2, CLR_M

	JNB SPL.1, SET_H




	CLR SPL.1

SET_M:	SETB SPL.2;分鐘位置

	AJMP TIME




SET_H:   SETB SPL.1;小時位置

CLR_M:	CLR SPL.2

	AJMP TIME

LJUMP_TIME:LJMP TIME

WAIT_UP: JNB P0.0,LJUMP_TIME

	CLR SET_BTN.0

	AJMP TIME







WAIT2_DL1:

	ACALL DELAY1

	ACALL DELAY1

	RET




HOUR_SHOW:

	JNB SPL.1, HOUR_SHOW_HRER

	JB SPL.0, HOUR_SHOW_HRER

	ACALL WAIT2_DL1

	RET

HOUR_SHOW_HRER:

	SETB P2.0

	SETB P2.1

	CLR A

	MOV A,HOUR

	MOV B,#0AH

	DIV AB




	MOVC A,@A+DPTR

	MOV P1,#00H

	MOV P1,A

	CLR P2.0

	;延時

	ACALL DELAY1

	SETB P2.0

	MOV P1,#00H

	 




	MOV A,B

	MOVC A,@A+DPTR

	MOV P1,A

	CLR P2.1

	;延時

	ACALL DELAY1

	SETB P2.1  




	MOV P1,#00H

	RET




MINUTE_SHOW:

	JNB SPL.2, MINUTE_SHOW_HERE

	JB SPL.0, MINUTE_SHOW_HERE

	ACALL WAIT2_DL1

	RET

MINUTE_SHOW_HERE:

	SETB P2.2

	SETB P2.3

	CLR A

	MOV A,MINUTE

	MOV B,#0AH

	DIV AB




	MOVC A,@A+DPTR

	MOV P1,#00H

	MOV P1,A

	CLR P2.2

	;延時

	ACALL DELAY1

	SETB P2.2

	MOV P1,#00H

	 




	MOV A,B

	MOVC A,@A+DPTR

	MOV P1,A

	CLR P2.3

	;延時

	ACALL DELAY1

	SETB P2.3




	MOV P1,#00H

	RET




DELAY1:	;短延時

	MOV R6,#03H

DL1:	MOV R7,08H

DL2:	DJNZ R7,DL2

	DJNZ R6,DL1

	RET

DELAY2:	;按鍵延時

	MOV R6,#0AH

DL21:	MOV R7,0AH

DL22:	DJNZ R7,DL22

	DJNZ R6,DL21

	RET

IT_1:    

	PUSH ACC

	PUSH B

	PUSH PSW

	INC COUNT1

	MOV A,COUNT1

 	CJNE A,#28H,RETI_LABLE

  

	INC COUNT2

	MOV COUNT1,#00H




	MOV A,COUNT2

	MOV B,#32H

	DIV AB

	MOV A,B

	JNZ  C2_OPT

	CPL P3.7;秒的閃爍

	CPL SPL.0

	;INC SPL;給閃爍設置值

C2_OPT:	MOV A,COUNT2

	CJNE A,#64H,RETI_LABLE




	INC SECOND

	MOV COUNT2,#00H

	MOV A,SECOND

	CJNE A,#3CH,RETI_LABLE;




	INC MINUTE

	MOV SECOND,#00H

	MOV A,MINUTE

	CJNE A,#3CH,RETI_LABLE;

 

	INC HOUR

	MOV MINUTE,#00H

	MOV A,HOUR

	CJNE A,#18H,RETI_LABLE




	MOV HOUR,#00H

RETI_LABLE:

	 POP PSW

	 POP B

	 POP ACC

	 RETI

TABLE: DB  3FH,06H,5BH,4FH,66H,6DH,7DH,07H,7FH,6FH,40H

 END 
關閉窗口

相關文章

主站蜘蛛池模板: 福利网站在线观看 | 福利小视频在线观看 | 亚洲精品在线免费 | 国产精品综合网 | 日韩av免费在线观看 | 欧美一区二区视频在线观看 | 我要看一级黄色片 | 一本伊人 | 人人艹人人 | 日韩在线视频免费 | 欧日韩av | 四虎在线观看视频 | 国产在线视频一区二区 | 蜜桃成人av| 一级国产片 | 成人一级黄色片 | 国产精品久久久久久久久久久久久久 | 国产福利91精品一区二区三区 | 久久r| 天天干天天操天天摸 | 在线日韩一区 | 亚洲一级精品 | 国产视频成人 | 久久久久亚洲精品 | 在线成人免费 | 亚洲精品一区二区三区精华液 | 成人一级视频 | 一起操在线| 香蕉视频在线看 | 国产美女一区二区 | 免费毛片在线播放 | 超碰在线小说 | 成人一区二区视频 | 国产深夜福利 | 国产欧美精品 | 精品一区三区 | 国产精品视频久久久 | 青青草福利视频 | 国产免费一级 | 亚洲激情一区二区 | 国产黄色片视频 |